CGI

 view release on metacpan or  search on metacpan

t/reserved_params.t  view on Meta::CPAN

#!perl

# POSTDATA, PUTDATA, PATCHDATA and XForms:Model hold the raw request body
# (or XForms model) - a client must not be able to set them through the
# query string, a form field or a multipart/related part, as an app could
# then not tell attacker supplied values from the real body (e.g. a plain
# HTML form posting POSTDATA={"admin":true} to a JSON endpoint)

use strict;
use warnings;

use Test::More;
use CGI;

$CGI::LIST_CONTEXT_WARN = 0;

my @reserved = ( 'POSTDATA', 'PUTDATA', 'PATCHDATA', 'XForms:Model' );
my $spoof    = join '&', map { CGI::escape($_) . '=evil' } @reserved;

sub request {
    my ( %args ) = @_;
    my $body = defined $args{body} ? $args{body} : '';
    CGI::initialize_globals();
    local $ENV{REQUEST_METHOD} = $args{method};
    local $ENV{QUERY_STRING}   = defined $args{query} ? $args{query} : '';
    local $ENV{CONTENT_TYPE}   = $args{type};
    local $ENV{CONTENT_LENGTH} = length $body;
    delete $ENV{CONTENT_TYPE} unless defined $args{type};
    local *STDIN;
    open STDIN, '<', \$body or die "In-memory filehandle failed: $!\n";
    binmode STDIN;
    return CGI->new;
}

sub reserved_values {
    my ( $q ) = @_;
    return { map { $_ => [ $q->multi_param($_) ] } grep { defined $q->param($_) } @reserved };
}

{
    my $q = request( method => 'GET', query => "$spoof&a=1" );
    is_deeply( reserved_values( $q ), {}, 'GET: reserved names in the query string are ignored' );
    is( $q->param('a'), 1, ' ... other params are kept' );
}

{
    my $q = request( method => 'POST', type => 'application/x-www-form-urlencoded', body => "$spoof&a=1" );
    is_deeply( reserved_values( $q ), {}, 'urlencoded POST: reserved names in the body are ignored' );
    is( $q->param('a'), 1, ' ... other params are kept' );
}

{
    my $body = join '',
        ( map { "--XB\r\nContent-Disposition: form-data; name=\"$_\"\r\n\r\nevil\r\n" } @reserved ),
        "--XB\r\nContent-Disposition: form-data; name=\"POSTDATA\"; filename=\"x.json\"\r\n\r\nevil\r\n",
        "--XB\r\nContent-Disposition: form-data; name=\"a\"\r\n\r\n1\r\n",
        "--XB\r\nContent-Disposition: form-data; name=\"f\"; filename=\"f.txt\"\r\n\r\nfile\r\n",
        "--XB--\r\n";
    my $q = request( method => 'POST', type => 'multipart/form-data; boundary=XB', body => $body, query => $spoof );
    is_deeply( reserved_values( $q ), {}, 'multipart POST: reserved names as fields, uploads or in the query string are ignored' );
    is( $q->param('a'), 1, ' ... other fields are kept' );
    my $fh = $q->upload('f');
    is( $fh && do { local $/; <$fh> }, 'file', ' ... as are other uploads' );
}

{
    my $q = request( method => 'POST', type => 'application/json', body => '{"real":1}', query => $spoof );



( run in 0.653 second using v1.01-cache-2.11-cpan-99fa8243a42 )