view release on metacpan or  search on metacpan

t/02git_Repository.t  view on Meta::CPAN

use strict;
use warnings;

use Test::More qw/no_plan/;
use Test::Exception;
use Test::utf8;

use Encode qw/decode_utf8/;
use Scalar::Util qw/set_prototype/;

BEGIN {
    # Mocking to allow testing regardless of the user's locale
    require I18N::Langinfo if $^O ne 'MSWin32';
    no warnings 'redefine';
    my $stub = sub {
        return "UTF-8" if $_[0] == I18N::Langinfo::CODESET();
    };
    set_prototype \&$stub, ($] <= 5.008009) ? '$' : '_';
    *I18N::Langinfo::langinfo = $stub;
    *CORE::GLOBAL::getpwuid = sub {
        wantarray
            ? ("test", "x", "1000", "1000", "", "", "T\x{c3}\x{a9}st", "/home/test", "/bin/bash")
            : "test";
    };
}

BEGIN { use_ok 'Git::Gitalist::Repository' }

dies_ok {
    my $proj = Git::Gitalist::Repository->new();
} 'New repository with no args';

use Path::Class;
my $gitdir = dir("t/lib/repositories/repo1");

my $proj = Git::Gitalist::Repository->new($gitdir);
isa_ok($proj, 'Git::Gitalist::Repository');
is($proj->path, $gitdir, 'repository path is set');
isa_ok($proj->path, 'Path::Class::Dir', 'repository path');
is($proj->name, qw/repo1/, 'repository name is set');
is($proj->description, qq/some test repository/, 'repository description loaded');
isa_ok($proj->last_change, 'DateTime', 'last_change');

my %references = %{$proj->references};
ok(keys %references >= 2, '->references hash has elements');
is($references{'36c6c6708b8360d7023e8a1649c45bcf9b3bd818'}->[0], 'tags/0.01', 'reference looks ok');
my @heads = @{$proj->heads};
ok(scalar @heads > 1, '->heads list has more than one element');
my $head = $heads[1];
isa_ok($head, 'Git::Gitalist::Head');
is($proj->head_hash, 'd6ddf8b26be63066e01d96a0922c87cd8d6e2270', 'head_hash for HEAD is correct');
is($proj->head_hash('refs/heads/master'), 'd6ddf8b26be63066e01d96a0922c87cd8d6e2270', 'head_hash for refs/heads/master is correct');
is($proj->head_hash('rafs/head/mister'), undef, 'head_hash for rafs/head/mister is undef');

ok(scalar @{$proj->tags} == 1, '->tags list has one element');

# Return an ::Object from a sha1
my $obj1 = $proj->get_object('729a7c3f6ba5453b42d16a43692205f67fb23bc1');
isa_ok($obj1, 'Git::Gitalist::Object::Tree');

my $obj3 = $proj->get_object($proj->head_hash);
isa_ok($obj3, 'Git::Gitalist::Object::Commit');

my $obj2 = $obj3->sha_by_path('dir1/file2');
isa_ok($obj2, 'Git::Gitalist::Object::Blob');
is($obj2->type, 'blob', 'sha_by_path obj is a blob');
is($obj2->content, "foo\n", 'sha_by_path obj content is correct');


like($proj->head_hash('HEAD'), qr/^([0-9a-fA-F]{40})$/, 'head_hash');

{
    my @tree = @{$obj3->tree};
    is(scalar @tree, 1, "tree array contains one entry.");
    isa_ok($tree[0], 'Git::Gitalist::Object', 'tree element 0');
}

$proj->{owner} = decode_utf8("T\x{c3}\x{a9}st") if $^O eq 'MSWin32';

my $owner = $proj->owner;