view release on metacpan or  search on metacpan

script/ru-perltidy  view on Meta::CPAN

use open qw/:std :utf8/;

use Getopt::Long qw(:config no_ignore_case);
use Perl::Tidy;
use Pod::Usage;
use Term::ANSIColor qw/:constants/;
use List::Util qw/max/;

use Octets::To::Unicode;

my $parse_options_ok = GetOptions(
    'help|h' => \( my $help = 0 ),
    'man'    => \( my $man  = 0 ),

    'e|ext=s'          => \( my $ext          = 'pm,pl,plx,t' ),
    'i|interpreters=s' => \( my $interpreters = 'perl,perl5' ),
    'n|encodings=s'    =>
      \( my $encodings = $ENV{'RU-ENCODINGS'} // 'utf-8,cp1251,koi8-r' ),
    'b|in-branch' => \( my $in_branch ),
    'd|in-dir=s'  => \( my $in_dir ),
);

if ( !$parse_options_ok ) {
    pod2usage(2);
}
elsif ($help) {
    pod2usage(
        -sections => "NAME|SYNOPSIS|DESCRIPTION|OPTIONS|SUBCOMMANDS",
        -verbose  => 99
    );
}
elsif ($man) {
    pod2usage( -exitval => 0, -verbose => 2 );
}
else {

    my @encodings = split /,/, $encodings;

    my @files =
      @ARGV ? @ARGV
      : test_files(
        [
              $in_branch ? change_files_in_branch()
            : $in_dir    ? map( file_find($_), split /,/, $in_dir )
            :              change_files()
        ],
        $ext,
        $interpreters
      );

    my $result     = 0;
    my $max_length = max map length, @files;

    for my $file (@files) {

        print "$file  ", " " x ( $max_length - length $file );

        my ( $unicode, $encoding ) = file_decode $file, \@encodings;

		local @ARGV = ();
        Perl::Tidy::perltidy(
            source      => \$unicode,
            destination => \my $tidied_code,
        );

        if ( defined $tidied_code and $unicode eq $tidied_code ) {
            print CYAN, "equals";
        }
        elsif ( defined $tidied_code and length $tidied_code ) {
            file_encode $file, $encoding, $tidied_code;
            print GREEN, "tidied";
        }
        else {
            print RED, "failed";
            $result = 1;
        }

        print RESET, " in ", YELLOW, $encoding, RESET, "\n";
    }

    exit $result;
}

__END__

=encoding utf-8

=head1 NAME

B<ru-perltidy> - утилита для форматирования файлов perltidy с определением их кодировки.

=head1 VERSION

Version 0.06

=head1 SYNOPSIS

    ru-perltidy [-h] [--man] [<files> ...] [--ext exts] [--interpreters interpreters] [--in-branch]

=head1 DESCRIPTION

Форматирует файлы через perltidy c определением их кодировки.

Есть 4 основные режима работы:

	# Отформатировать все изменённые, но ещё не закомиченные файлы:
	$ ru-perltidy
	
	# Обработать изменённые и закомиченные файлы в ветке (branch-е):
	$ ru-perltidy --in-branch

	# Обработать файлы в директориях:
	$ ru-perltidy --in-dir .,/tmp/mydir

	# Отформатировать указанные файлы:
	$ ru-perltidy file1 /root/file2
	
С помощью опции -e (--ext) можно указать расширения файлов для форматирования (по умолчанию это pm,pl,plx,t):

	$ ru-perltidy -e pm,t