view release on metacpan or  search on metacpan

plugins/spod5  view on Meta::CPAN

    
    
    <div class="presentation">
    
    <div class="slide">
    <xsl:value-of select="meta/title_top"/>
    <h1><xsl:value-of select="meta/title"/></h1>
    <h3><xsl:value-of select="meta/author"/></h3>
    <h4><xsl:value-of select="meta/company"/></h4>
    <xsl:value-of select="meta/title_bottom"/>
    </div>
    
    <xsl:apply-templates select="*[starts-with(name(), 'head')]"/>
    
    </div>
    
    </body>
    </html>
</xsl:template>

<xsl:template match="pod">
 <xsl:apply-templates/>
</xsl:template>

<xsl:template match="para">
  <xsl:choose>
    <xsl:when test="./*[name() != 'orderedlist' and name() != 'itemizedlist']">
      <p>
        <xsl:apply-templates/>
      </p>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="verbatim">
  <pre class="verbatim"><xsl:apply-templates/></pre>
</xsl:template>

<xsl:template match="link">
  <xsl:choose>
    <xsl:when test='string-length(@section) and not( string-length(@page) )'>
      <xsl:choose>
        <xsl:when test='starts-with(@section, "/")'>
          <a href="/view{@section}"><xsl:apply-templates/></a>
        </xsl:when>
        <xsl:otherwise>
          <a href="#{translate(@section,' ','-')}"><xsl:apply-templates/></a>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:when>
    <xsl:otherwise>
      <a href="./{@page}#{translate(@section,' ','-')}"><xsl:apply-templates/></a>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="xlink">
  <a href="{@href}"><xsl:apply-templates/></a><img src="/img/out.png"/>
</xsl:template>

<xsl:template match="head1">
  <div class="slide"><h1><xsl:apply-templates/></h1>
  <xsl:apply-templates select="following-sibling::*[generate-id(preceding-sibling::head1[1]) = generate-id(current())]"/>
  </div>
</xsl:template>

<xsl:template match="head2">
  <h2><xsl:apply-templates/></h2>
</xsl:template>

<xsl:template match="head3">
  <h3><xsl:apply-templates/></h3>
</xsl:template>

<xsl:template match="head4">
  <h4><xsl:apply-templates/></h4>
</xsl:template>

<xsl:template match="itemizedlist">
  <ul>
    <xsl:choose>
        <xsl:when test="@indent_width = -1">
            <xsl:attribute name="class">incremental</xsl:attribute>
        </xsl:when>
        <xsl:when test="@indent_width = -2">
            <xsl:attribute name="class">incremental show-first</xsl:attribute>
        </xsl:when>
    </xsl:choose>
    <xsl:apply-templates/>
  </ul>
</xsl:template>

<xsl:template match="orderedlist">
  <ol>
    <xsl:choose>
        <xsl:when test="@indent_width = -1">
            <xsl:attribute name="class">incremental</xsl:attribute>
        </xsl:when>
        <xsl:when test="@indent_width = -2">
            <xsl:attribute name="class">incremental show-first</xsl:attribute>
        </xsl:when>
    </xsl:choose>
    <xsl:apply-templates/>
  </ol>
</xsl:template>

<xsl:template match="listitem">
  <li><xsl:apply-templates/></li>
</xsl:template>

<xsl:template match="itemtext">
  <span class="itemtext"><xsl:apply-templates/></span>
</xsl:template>

<xsl:template match="hr">
  <hr/>
</xsl:template>