view release on metacpan or  search on metacpan

lib/POD2/ES/perlfunc.pod  view on Meta::CPAN

verdadero si tuvo éxito, sino, falso. Vea el ejemplo que está en
L<C<die>|/die LISTA>.

En sistemas que soportan L<fchdir(2)>, puede pasarle un identificador de
archivo o un identificador de directorio como argumento. En sistemas que no
admiten L<fchdir(2)>, pasarle un identificador de archivo lanza una excepción.

=item chmod LISTA
X<chmod> X<permission> X<mode> X<permisos> X<modo>

=for Pod::Functions changes the permissions on a list of files

Cambia los permisos de una lista de archivos. El primer elemento de la lista
debe ser un modo numérico, que normalmente estará en octal, y que,
definitivamente, I<no> debe ser una cadena de dígitos en octal: C<0644> es
correcto, C<"0644"> no lo es. Devuelve el número de archivos cambiados con
éxito. Vea también L<C</oct>|/oct EXPR> si todo lo que tiene es una cadena.

    my $cnt = chmod 0755, "foo", "bar";
    chmod 0755, @ejecutables;
    my $mode = "0644"; chmod $mode, "foo";      # !!! establece modo a
                                                # --w----r-T
    my $modo = "0644"; chmod oct($modo), "foo"; # este es el mejor
    my $mode = 0644;   chmod $mode, "foo";      # este es mejor

En sistemas que soporten L<fchmod(2)>, puede pasar identificadores de archivo
entre los archivos. En sistemas que no admiten L<fchmod(2)>, pasar un
identificador de archivo lanza una excepción. Identificadores de archivo se
deben pasar como comodines o referencias a comodines para que sean reconocidos;
las palabras sueltas se consideran como nombres de archivo.

    open(my $fh, "<", "foo");
    my $permisos = (stat $fh)[2] & 07777;
    chmod($permisos | 0600, $fh);

También puede importar las constantes simbólicas C<S_I*> desde el módulo
L<C<Fcntl>|Fcntl>:

    use Fcntl qw( :mode );
    chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @ejecutables;
    # Idéntico a chmod 0755 del ejemplo anterior.

Cuestiones de portabilidad: L<perlport/chmod>.

=item chomp VARIABLE
X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol> X<nueva línea>

=item chomp( LISTA )

=item chomp

=for Pod::Functions remove a trailing record separator from a string

Esta versión segura de L<C<chop>|/chop VARIABLE>, quita cualquier cadena
restante que corresponda al valor actual de L<C<$E<sol>>|perlvar/$E<sol>>
(también conocido como $INPUT_RECORD_SEPARATOR -separador de registros en
entrada- en el módulo L<C<English>|English>). Devuelve el número total de
caracteres eliminados de todos sus argumentos. Se utiliza a menudo para
eliminar el carácter de nueva línea del final de un registro de entrada
cuando es importante que el registro al final le pueda faltar ese carácter. En
modo párrafo (C<$/ = ''>), elimina todos los caracteres de nueva línea de la
cadena. En modo chupón (C<$/ = undef>) o en modo de registros de longitud fija
(L<C<$E<sol>>|perlvar/$E<sol>> es una referencia a un entero o algo parecido;
ver L<perlvar>), L<C<chomp>|/chomp VARIABLE> no elimina nada. Si se omite
VARIABLE, usa L<C<$_>|perlvar/$_>. Ejemplo:

    while (<>) {
        chomp;  # evitar \n en el último campo
        my @array = split(/:/);
        # ...
    }

Si VARIABLE es un hash, recorta los valores del hash, pero no sus claves,
reiniciando el iterador L<C<each>|/each HASH> durante el proceso.

Puede realmente recortar cualquier cosa que sea un valor-izquierda, incluyendo
una asignación:

    chomp(my $cwd = `pwd`);
    chomp(my $respuesta = <STDIN>);

Si recorta una lista, cada elemento es recortado y se devuelve el número total
de caracteres eliminados.

Nota que los paréntesis son necesarios cuando esté recortando cualquier cosa
que no sea una simple variable. Esto es porque C<chomp $cwd = `pwd`;> es
interpretado como C<(chomp $cwd) = `pwd`;>, en vez de un C<chomp( $cwd = `pwd`
)> que es lo que se esperaba. Similarmente, C<chomp $a, $b> es interpretado
como C<chomp($a), $b> en vez de un C<chomp($a, $b)>.

=item chop VARIABLE
X<chop>

=item chop( LISTA )

=item chop

=for Pod::Functions remove the last character from a string

Recorta el último carácter de un string y devuelve el carácter recortado. Es
más eficiente que C<s/.$//s> porque ni escanea ni copia el string. Si se omite
VARIABLE, recorta L<C<$_>|perlvar/$_>. Si VARIABLE es un hash, recorta los
valores del hash, pero no sus claves, reiniciando el iterador L<C<each>|/each
HASH> durante el proceso.

Puede realmente recortar cualquier cosa que sea un valor-izquierda, incluyendo
una asignación.

Si recorta una lista, cada elemento es recortado. Solo se devuelve el valor del
último L<C<chop>|/chop VARIABLE>.

Note que L<C<chop>|/chop VARIABLE> devuelve el último carácter. Para devolver
todos menos el último carácter, use C<substr($string, 0, -1)>.

Vea también L<C<chomp>|/chomp VARIABLE>.

=item chown LISTA
X<chown> X<owner> X<user> X<group> X<propietario> X<usuario> X<grupo>

=for Pod::Functions change the ownership on a list of files