view release on metacpan or  search on metacpan

lib/Iterator/Flex/Map.pm  view on Meta::CPAN

package Iterator::Flex::Map;

# ABSTRACT: Map Iterator Class

use v5.28;
use strict;
use warnings;
use experimental 'signatures';

our $VERSION = '0.33';

use Iterator::Flex::Utils qw( STATE THROW EXHAUSTION :IterAttrs :IterStates );
use Iterator::Flex::Factory 'to_iterator';
use Ref::Util;
use parent 'Iterator::Flex::Base';

use namespace::clean;






























sub new ( $class, $code, $iterable, $pars = {} ) {
    throw_failure( parameter => q{'code' parameter is not a coderef} )
      unless Ref::Util::is_coderef( $code );

    $class->SUPER::new( { code => $code, src => $iterable }, $pars );
}

sub construct ( $class, $state ) {

    throw_failure( parameter => q{'state' parameter must be a HASH reference} )
      unless Ref::Util::is_hashref( $state );

    my ( $code, $src ) = @{$state}{qw[ code src ]};

    $src
      = to_iterator( $src, { ( +EXHAUSTION ) => THROW } );

    my @values;
    my $self;
    my $iterator_state;

    return {
        ( +_NAME ) => 'imap',

        ( +_SELF ) => \$self,

        ( +STATE ) => \$iterator_state,

        ( +NEXT ) => sub {
            return $self->signal_exhaustion if $iterator_state == IterState_EXHAUSTED;

            unless ( @values ) {
                eval {
                    my $value = $src->();
                    local $_ = $value;
                    @values = $code->();
                    1;
                } or do {
                    die $@
                      unless Ref::Util::is_blessed_ref( $@ )
                      && $@->isa( 'Iterator::Flex::Failure::Exhausted' );
                    return $self->signal_exhaustion;
                };
            }
            return shift @values;
        },

        ( +RESET )    => sub { @values = () },
        ( +REWIND )   => sub { @values = () },
        ( +_DEPENDS ) => $src,
    };
}


__PACKAGE__->_add_roles( qw[
      State::Closure
      Next::ClosedSelf
      Reset::Closure
      Rewind::Closure
] );

1;

#
# This file is part of Iterator-Flex
#
# This software is Copyright (c) 2018 by Smithsonian Astrophysical Observatory.
#
# This is free software, licensed under:
#
#   The GNU General Public License, Version 3, June 2007
#

__END__

=pod

=for :stopwords Diab Jerius Smithsonian Astrophysical Observatory

=head1 NAME

Iterator::Flex::Map - Map Iterator Class

=head1 VERSION

version 0.33

=head1 METHODS

=head2 new

  $iterator = Ierator::Flex::Map->new( $coderef, $iterable, ?\%pars );

Returns an iterator equivalent to running C<map> on C<$iterable> with
the specified code.  If C<$coderef> returns a list, the elements will
be returned singly.

C<CODE> is I<not> run if C<$iterable> is exhausted.

C<$iterable> is converted into an iterator via L<Iterator::Flex::Factory/to_iterator> if required.