view release on metacpan or  search on metacpan

lib/Iterator/Flex/Array.pm  view on Meta::CPAN

package Iterator::Flex::Array;

# ABSTRACT: Array Iterator Class

use v5.28;
use strict;
use warnings;

our $VERSION = '0.33';

use Iterator::Flex::Utils ':IterAttrs', ':IterStates', 'throw_failure';
use Ref::Util;
use namespace::clean;
use experimental 'signatures';

use parent 'Iterator::Flex::Base';






























sub new ( $class, $array, $pars = {} ) {
    throw_failure( parameter => 'argument must be an ARRAY reference' )
      unless Ref::Util::is_arrayref( $array );

    $class->SUPER::new( { array => $array }, $pars );
}


sub construct ( $class, $state ) {

    throw_failure( parameter => q{'state' parameter must be a HASH reference} )
      unless Ref::Util::is_hashref( $state );

    my ( $arr, $prev, $current, $next )
      = @{$state}{qw[ array prev current next ]};

    throw_failure( parameter => q{state 'array' parameter must be a HASH reference} )
      unless Ref::Util::is_arrayref( $arr );

    my $len = @$arr;

    $next = 0 unless defined $next;

    throw_failure( parameter => q{illegal value for state 'prev' argument} )
      if defined $prev && ( $prev < 0 || $prev >= $len );

    throw_failure( parameter => q{illegal value for state 'current' argument} )
      if defined $current && ( $current < 0 || $current >= $len );

    throw_failure( parameter => q{illegal value for state 'next' argument} )
      if $next < 0 || $next > $len;

    my $self;
    my $iterator_state;

    return {

        ( +_NAME ) => 'iarray',

        ( +_SELF ) => \$self,

        ( +STATE ) => \$iterator_state,

        ( +RESET ) => sub {
            $prev = $current = undef;
            $next = 0;
        },

        ( +REWIND ) => sub {
            $next = 0;
        },

        ( +PREV ) => sub {
            return defined $prev ? $arr->[$prev] : undef;
        },

        ( +CURRENT ) => sub {
            return defined $current ? $arr->[$current] : undef;
        },

        ( +NEXT ) => sub {
            if ( $next == $len ) {
                # if first time through, set prev
                $prev = $current
                  if $iterator_state != IterState_EXHAUSTED;
                return $current = $self->signal_exhaustion;
            }
            $prev    = $current;
            $current = $next++;

            return $arr->[$current];
        },

        ( +FREEZE ) => sub {
            return [
                $class,
                {
                    array   => $arr,