view release on metacpan or  search on metacpan

lib/Email/Abstract/MailMessage.pm  view on Meta::CPAN

use strict;
package Email::Abstract::MailMessage;
# ABSTRACT: Email::Abstract wrapper for Mail::Message
$Email::Abstract::MailMessage::VERSION = '3.010';
use Email::Abstract::Plugin;
BEGIN { @Email::Abstract::MailMessage::ISA = 'Email::Abstract::Plugin' };

sub target { "Mail::Message" }

sub construct {
    require Mail::Message;
    my ($class, $rfc822) = @_;
    Mail::Message->read($rfc822);
}

sub get_header {
    my ($class, $obj, $header) = @_;
    $obj->head->get($header);
}

sub get_body {
    my ($class, $obj) = @_;
    $obj->decoded->string;
}

sub set_header {
    my ($class, $obj, $header, @data) = @_;
    $obj->head->delete($header);
    $obj->head->add($header, $_) for @data;
}

sub set_body {
    my ($class, $obj, $body) = @_;
    $obj->body(Mail::Message::Body->new(data => $body));
}

sub as_string {
    my ($class, $obj) = @_;
    $obj->string;
}

1;

#pod =head1 DESCRIPTION
#pod
#pod This module wraps the Mail::Message mail handling library with an
#pod abstract interface, to be used with L<Email::Abstract>
#pod
#pod =head1 SEE ALSO
#pod
#pod L<Email::Abstract>, L<Mail::Message>.
#pod
#pod =cut

__END__

=pod

=encoding UTF-8

=head1 NAME

Email::Abstract::MailMessage - Email::Abstract wrapper for Mail::Message

=head1 VERSION

version 3.010

=head1 DESCRIPTION

This module wraps the Mail::Message mail handling library with an
abstract interface, to be used with L<Email::Abstract>

=head1 PERL VERSION

This library should run on perls released even a long time ago.  It should
work on any version of perl released in the last five years.

Although it may work on older versions of perl, no guarantee is made that the
minimum required version will not be increased.  The version may be increased
for any reason, and there is no promise that patches will be accepted to
lower the minimum required perl.