view release on metacpan or  search on metacpan

lib/Dist/Zilla/Plugin/Codeberg/Update.pm  view on Meta::CPAN

package Dist::Zilla::Plugin::Codeberg::Update 2.0100;

use Modern::Perl;
use Carp;
use JSON::MaybeXS;
use Moose;
use List::Util  qw(first);
use URL::Encode qw(url_encode_utf8);

our $AUTHORITY = 'cpan:GEEKRUTH';    # AUTHORITY
extends 'Dist::Zilla::Plugin::Codeberg';
with 'Dist::Zilla::Role::AfterRelease';

sub after_release {
   my $self = shift;

   return if ( !$self->_has_credentials );

   my $repo_name = $self->_get_repo_name( $self->_credentials->{login} );
   if ( not $repo_name ) {
      $self->log('cannot update Codeberg repository info');
      return;
   }

   my $params = {
      name        => ( $repo_name =~ /\/(.*)$/ )[0],
      description => $self->zilla->abstract,
   };

   $self->log('Updating Codeberg repository info');

   my $url
      = $self->api . '/repos/' . $repo_name;    # url_encode_utf8($repo_name);

   my $current = $self->_current_params($url);
   if (  $current
      && ( $current->{name}        || q{} ) eq $params->{name}
      && ( $current->{description} || q{} ) eq $params->{description} ) {

      $self->log('Codeberg repo info is up to date');
      return;
   }
   my $headers = $self->_auth_headers;
   $headers->{'content-type'} = 'application/json';

   $self->log_debug("Sending PATCH $url");
   my $response = HTTP::Tiny->new->request(
      'PATCH', $url,
      {
         content => encode_json($params),
         headers => $headers,
      }
   );

   my $repo = $self->_check_response($response);

   return if not $repo;
}

sub _current_params {
   my $self = shift;
   my ($url) = @_;

   my $http = HTTP::Tiny->new;

   $self->log_debug("Sending GET $url");
   my $response = $http->request( 'GET', $url );

   return $self->_check_response($response);
}

__PACKAGE__->meta->make_immutable;

1;

=pod

=encoding UTF-8