view release on metacpan or  search on metacpan

lib/CGI/Application/Plugin/Authentication/Store.pm  view on Meta::CPAN

=head2 save

This method accepts a hash of parameters and values and will save those parameters in the store.

=cut

sub save {
    my $self = shift;
    my $class = ref $self;
    die "save must be implemented in the $class subclass";
}

=head2 delete

This method accepts a list of parameters and will delete those parameters from the store.

=cut 

sub delete {
    my $self = shift;
    my $class = ref $self;
    die "delete must be implemented in the $class subclass";
}

=head2 clear

A call to this method will remove all information about the current user out of the store (should
be provided by the subclass, but is not required to be).

=cut

sub clear {
    my $self = shift;
    $self->delete('username', 'login_attempts', 'last_access', 'last_login');
}


=head1 OTHER METHODS

The following methods are also provided by the L<CGI::Application::Plugin::Authentication::Store>
base class.

=head2 new

This is a constructor that can create a new Store object.  It requires an Authentication object as its
first parameter, and any number of other parameters that will be used as options depending on which
Store object is being created.  You shouldn't need to call this as the Authentication plugin takes care
of creating Store objects.

=cut

sub new {
    my $class   = shift;
    my $self    = {};
    my $authen  = shift;
    my @options = @_;

    bless $self, $class;
    $self->{authen} = $authen;
    Scalar::Util::weaken( $self->{authen} );    # weaken circular reference
    $self->{options} = \@options;
    $self->initialize;
    return $self;
}

=head2 initialize

This method will be called right after a new Store object is created.  So any startup customizations
can be dealt with here.

=cut

sub initialize {
    my $self = shift;
    # override this in the subclass if you need it
    return;
}

=head2 options

This will return a list of options that were provided when this store was configured by the user.

=cut

sub options {
    my $self = shift;
    my @options = @{$self->{options}};
    return @options[0..$#options];
}

=head2 authen

This will return the underlying L<CGI::Application::Plugin::Authentication> object.  In most cases it will
not be necessary to access this.

=cut

sub authen {
    my $self = shift;
    $self->{authen};
}


=head1 SEE ALSO

L<CGI::Application::Plugin::Authentication::Store>, L<CGI::Application::Plugin::Authentication>, perl(1)


=head1 AUTHOR

Cees Hek <ceeshek@gmail.com>


=head1 LICENCE AND COPYRIGHT

Copyright (c) 2005, SiteSuite. All rights reserved.

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself.