view release on metacpan or  search on metacpan

lib/Bio/FastParsers/Hmmer/Standard.pm  view on Meta::CPAN

package Bio::FastParsers::Hmmer::Standard;
# ABSTRACT: Front-end class for standard HMMER parser
# CONTRIBUTOR: Arnaud DI FRANCO <arnaud.difranco@gmail.com>
$Bio::FastParsers::Hmmer::Standard::VERSION = '0.221230';
use Moose;
use namespace::autoclean;

# TODO: check if autodie is actually needed here
use autodie;

use List::AllUtils qw(indexes firstidx mesh);

extends 'Bio::FastParsers::Base';

use Bio::FastParsers::Constants qw(:files);
use aliased 'Bio::FastParsers::Hmmer::Standard::Iteration';


# public attributes (inherited)


# private attributes

has '_iterations'  => (
    traits  => ['Array'],
    is      => 'ro',
    isa     => 'ArrayRef[Bio::FastParsers::Hmmer::Standard::Iteration]',
    writer  => '_set_iterations',
    handles => {
         next_iteration  => 'shift',
          get_iteration  => 'get',
          all_iterations => 'elements',
        count_iterations => 'count',
    },
);

sub BUILD {
    my $self = shift;

    my $content = $self->file->slurp;           # includes autodie
    my @iter_blocks = $content =~ m{ ( ^Query: .+?  ^//$ ) }xmsg;
    my @iterations = map { Iteration->new($_) } @iter_blocks;
    $self->_set_iterations( \@iterations );

    return;
}


# aliases

sub next_query {
    return shift->next_iteration;
}

sub get_query {                             ## no critic (RequireArgUnpacking)
    return shift->get_iteration(@_);
}

sub all_queries {
    return shift->all_iterations;
}

sub count_queries {
    return shift->count_iterations;
}