view release on metacpan or  search on metacpan

lib/App/lcpan/Cmd/script2rel.pm  view on Meta::CPAN

use warnings;

require App::lcpan;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2023-09-26'; # DATE
our $DIST = 'App-lcpan'; # DIST
our $VERSION = '1.074'; # VERSION

our %SPEC;

$SPEC{'handle_cmd'} = {
    v => 1.1,
    summary => 'Get release(s) of script(s)',
    args => {
        %App::lcpan::common_args,
        %App::lcpan::scripts_args,
        %App::lcpan::full_path_args,
        %App::lcpan::all_args,
    },
};
sub handle_cmd {
    my %args = @_;

    my $state = App::lcpan::_init(\%args, 'ro');
    my $dbh = $state->{dbh};

    my $scripts = $args{scripts};
    my $scripts_s = join(",", map {$dbh->quote($_)} @$scripts);

    my $sth = $dbh->prepare("SELECT
  script.name script,
  file.cpanid author,
  file.name release
FROM script
LEFT JOIN file ON script.file_id=file.id
WHERE script.name IN ($scripts_s)
ORDER BY file.id DESC");
    $sth->execute;

    my @res;
    my %mem;
    while (my $row = $sth->fetchrow_hashref) {
        unless ($args{all}) {
            next if $mem{$row->{script}}++;
        }
        if ($args{full_path}) {
            $row->{release} = App::lcpan::_fullpath(
                $row->{release}, $state->{cpan}, $row->{author});
        } else {
            $row->{release} = App::lcpan::_relpath(
                $row->{release}, $row->{author});
        }
        delete $row->{author};
        push @res, $row;
    }

    if (@$scripts == 1) {
        @res = map { $_->{release} } @res;
        if (!@res) {
            return [404, "No such script"];
        } elsif (@res == 1) {
            return [200, "OK", $res[0]];
        } else {
            return [200, "OK", \@res];
        }
    }

    [200, "OK", \@res, {'table.fields' => [qw/script release/]}];
}

1;
# ABSTRACT: Get release(s) of script(s)

__END__

=pod

=encoding UTF-8

=head1 NAME

App::lcpan::Cmd::script2rel - Get release(s) of script(s)

=head1 VERSION

This document describes version 1.074 of App::lcpan::Cmd::script2rel (from Perl distribution App-lcpan), released on 2023-09-26.

=head1 FUNCTIONS


=head2 handle_cmd

Usage:

 handle_cmd(%args) -> [$status_code, $reason, $payload, \%result_meta]

Get release(s) of script(s).

This function is not exported.

Arguments ('*' denotes required arguments):

=over 4

=item * B<all> => I<bool>

(No description)

=item * B<cpan> => I<dirname>

Location of your local CPAN mirror, e.g. E<sol>pathE<sol>toE<sol>cpan.

Defaults to C<~/cpan>.

=item * B<full_path> => I<bool>

(No description)

=item * B<index_name> => I<filename> (default: "index.db")