view release on metacpan or  search on metacpan

lib/App/lcpan/Cmd/bugs_open.pm  view on Meta::CPAN

package App::lcpan::Cmd::bugs_open;

use 5.010001;
use strict;
use warnings;
use Log::ger;

require App::lcpan;
require App::lcpan::Cmd::dist_meta;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2022-03-27'; # DATE
our $DIST = 'App-lcpan-CmdBundle-bugs'; # DIST
our $VERSION = '0.004'; # VERSION

our %SPEC;

$SPEC{handle_cmd} = {
    v => 1.1,
    summary => "Open a module/dist's bugtracker page in browser",
    args => {
        %App::lcpan::common_args,
        %App::lcpan::mod_or_dist_args,
    },
};
sub handle_cmd {
    my %args = @_;

    my $state = App::lcpan::_init(\%args, 'ro');
    my $dbh = $state->{dbh};

    my ($dist, $file_id);
    {
        # first find dist
        if (($file_id) = $dbh->selectrow_array(
            "SELECT id FROM file WHERE dist_name=? AND is_latest_dist", {}, $args{module_or_dist})) {
            $dist = $args{module_or_dist};
            last;
        }
        # try mod
        if (($file_id, $dist) = $dbh->selectrow_array("SELECT m.file_id, f.dist_name FROM module m JOIN file f ON m.file_id=f.id WHERE m.name=?", {}, $args{module_or_dist})) {
            last;
        }
    }
    $file_id or return [404, "No such module/dist '$args{module_or_dist}'"];

    my $res = App::lcpan::Cmd::dist_meta::handle_cmd(%args, dist=>$dist);
    return [412, $res->[1]] unless $res->[0] == 200;
    my $meta = $res->[2];

    my $url;
    unless ($meta->{resources} &&
                $meta->{resources}{bugtracker} &&
                ($url = $meta->{resources}{bugtracker}{web})) {
        return [412, "No bugtracker web URL specified in the distmeta's resources"];
    }

    require Browser::Open;
    my $err = Browser::Open::open_browser($url);
    return [500, "Can't open browser"] if $err;
    [200];

}

1;
# ABSTRACT: Open a module/dist's bugtracker page in browser

__END__

=pod

=encoding UTF-8

=head1 NAME

App::lcpan::Cmd::bugs_open - Open a module/dist's bugtracker page in browser

=head1 VERSION

This document describes version 0.004 of App::lcpan::Cmd::bugs_open (from Perl distribution App-lcpan-CmdBundle-bugs), released on 2022-03-27.

=head1 DESCRIPTION

This module handles the L<lcpan> subcommand C<bugs-open>.

=head1 FUNCTIONS


=head2 handle_cmd

Usage:

 handle_cmd(%args) -> [$status_code, $reason, $payload, \%result_meta]

Open a moduleE<sol>dist's bugtracker page in browser.

This function is not exported.

Arguments ('*' denotes required arguments):

=over 4

=item * B<cpan> => I<dirname>

Location of your local CPAN mirror, e.g. E<sol>pathE<sol>toE<sol>cpan.