view release on metacpan or  search on metacpan

lib/App/Netdisco/Worker/Runner.pm  view on Meta::CPAN

package App::Netdisco::Worker::Runner;

use Dancer qw/:moose :syntax/;
use Dancer::Plugin::DBIC 'schema';

use App::Netdisco::Util::CustomFields;
use App::Netdisco::Transport::Python ();
use App::Netdisco::Util::Device 'get_device';
use App::Netdisco::Util::Permission qw/acl_matches acl_matches_only/;
use aliased 'App::Netdisco::Worker::Status';

use Try::Tiny;
use Time::HiRes ();
use Module::Load ();
use Scope::Guard 'guard';
use Storable 'dclone';
use Sys::SigAction 'timeout_call';

use Moo::Role;
use namespace::clean;

with 'App::Netdisco::Worker::Loader';
has 'job' => ( is => 'rw' );

# mixin code to run workers loaded via plugins
sub run {
  my ($self, $job) = @_;

  die 'cannot reuse a worker' if $self->job;
  die 'bad job to run()'
    unless ref $job eq 'App::Netdisco::Backend::Job';

  $self->job($job);
  $job->device( get_device($job->device) )
    unless scalar grep {$job->action eq $_} @{ setting('job_targets_prefix') };
  $self->load_workers();

  # clean up and finalise job status when we exit
  my $statusguard = guard {
    if (var('live_python')) {
      try { App::Netdisco::Transport::Python->runner->finish };
      try { App::Netdisco::Transport::Python->runner->kill_kill };
      try { unlink App::Netdisco::Transport::Python->context->filename };
    }
    $job->finalise_status;
  };

  my @newuserconf = ();
  my @userconf = @{ dclone (setting('device_auth') || []) };

  # reduce device_auth by only/no
  if (ref $job->device) {
    foreach my $stanza (@userconf) {
      my $no   = (exists $stanza->{no}   ? $stanza->{no}   : undef);
      my $only = (exists $stanza->{only} ? $stanza->{only} : undef);

      next if $no and acl_matches($job->device, $no);
      next if $only and not acl_matches_only($job->device, $only);

      push @newuserconf, dclone $stanza;
    }

    # per-device action but no device creds available
    return $job->add_status( Status->defer('deferred job with no device creds') )
      if 0 == scalar @newuserconf && $self->transport_required;
  }

  # back up and restore device_auth
  my $configguard = guard { set(device_auth => \@userconf) };
  set(device_auth => \@newuserconf);

  my $runner = sub {