view release on metacpan or  search on metacpan

lib/App/DiffCPANReleases.pm  view on Meta::CPAN

package App::DiffCPANReleases;

our $DATE = '2017-08-07'; # DATE
our $VERSION = '0.001'; # VERSION

use 5.010001;
use strict;
use warnings;
use Log::ger;

our %SPEC;

sub _get_release {
    require File::Util::Tempdir;

    my $rel = shift;
    log_trace "Resolving %s ...", $rel;

    my $tempdir = File::Util::Tempdir::get_tempdir();

  USE_PATH:
    {
        if ($rel =~ m!/! || $rel =~ /\.tar(\.\w+)?\z/) {
            return [404, "No such release tarball file '$rel'"] unless -f $rel;
            return [200, "OK (file)", $rel];
        }
    }

    my ($dist, $ver);
    if ($rel =~ /\A(\w+(?:-\w+)*)\@([0-9][\w.-]*)\z/) {
        $dist = $1;
        $ver = $2;
    } elsif ($rel =~ /\A\w+(?:-\w+)*\z/) {
        $dist = $rel;
    } else {
        return [400, "Invalid release syntax: $rel, please use ".
                    "path or DISTNAME\@VERSION or DISTNAME"];
    }

  USE_CACHE:
    {
        last unless $ver;
        for my $ext (qw/.tar.gz .tar.bz2 .tar.xz .tar/) {
            my $path = "$tempdir/$dist-$ver$ext";
            return [200, "OK (cached URL)", $path] if -f $path;
        }
    }

    my $url;
  RESOLVE:
    {
        require App::cpm::Resolver::MetaCPAN;
        my $resolver = App::cpm::Resolver::MetaCPAN->new;
        (my $pkg = $dist) =~ s/-/::/g;
        my $version_range; $version_range = "==$ver" if defined $ver;
        my $res = $resolver->resolve({
            package => $pkg,
            (version_range => $version_range) x !!(defined $version_range),
        });
        log_trace "Result from MetaCPAN resolver: %s", $res;
        return [500, "Can't resolve $rel: $res->{error}"] if $res->{error};
        $url = $res->{uri};
    }

  DOWNLOAD:
    {
        my ($filename) = $url =~ m!.+/([^/]+)\z!;
        $filename or return [412, "BUG? Can't extract filename from URL $url"];
        my $path = "$tempdir/$filename";
        return [200, "OK (cached URL)", $path] if -f $path;

        require HTTP::Tiny;
        log_trace "Downloading %s ...", $url;
        my $res = HTTP::Tiny->new->get($url);
        return [$res->{status}, "Can't download $url: $res->{reason}"]
            unless $res->{success};

        open my $fh, ">", $path or return [500, "Can't open $path: $!"];
        binmode($fh);
        print $fh $res->{content};
        close $fh or return [500, "Can't write $path: $!"];
        return [200, "(downloaded URL)", $path];
    }
}