AnyEvent-MCP
view release on metacpan or search on metacpan
lib/AnyEvent/MCP/Client/HTTP.pm view on Meta::CPAN
outstanding requests; a later operation can initialize again. Legacy GET
streams and the old separate SSE endpoint transport are not implemented.
=back
=cut
package AnyEvent::MCP::Client::HTTP;
use common::sense;
use parent "AnyEvent::MCP::Client";
use AnyEvent::HTTP ();
use JSON::XS ();
use MIME::Base64 ();
use Scalar::Util qw(weaken);
use AnyEvent::MCP::Config ();
sub new {
my ($class, %kv) = @_;
if (defined $kv{name}) {
my $settings = (AnyEvent::MCP::Config::global_config)->{section}{"client $kv{name}"} || {};
%kv = (
(map { exists $settings->{$_} ? ($_ => $settings->{$_}) : () }
qw(url bearer timeout)),
%kv,
);
}
defined $kv{url}
or die "HTTP client requires a URL\n";
!exists $kv{username} && !exists $kv{password}
or die "HTTP Basic authentication is unsupported\n";
die "Invalid bearer token\n" if defined $kv{bearer} && $kv{bearer} !~ /\A[^\s]+\z/;
$class->SUPER::new (timeout => 300, %kv)
}
sub _send {
my ($self, $message, $done) = @_;
my $key = exists $message->{id} && !exists $message->{result} && !exists $message->{error}
? $message->{id} : "send:" . ++$self->{send_id};
my $generation = $self->{generation};
my %headers = (
%{$self->{headers} || {}},
"content-type" => "application/json",
accept => "application/json, text/event-stream",
);
$headers{authorization} = "Bearer $self->{bearer}" if defined $self->{bearer};
$headers{"mcp-protocol-version"} = $self->{protocol_version} if defined $self->{protocol_version};
$headers{"mcp-session-id"} = $self->{session}
if $self->{protocol_version} lt "2026" && defined $self->{session};
if ($self->{protocol_version} ge "2026" && exists $message->{method} && exists $message->{id}) {
$headers{"mcp-method"} = $message->{method};
if ($message->{method} =~ /\A(?:tools\/call|prompts\/get|resources\/read)\z/) {
my $name = exists $message->{params}{name} ? $message->{params}{name} : $message->{params}{uri};
$headers{"mcp-name"} = $name =~ /[^\x20-\x7e]/
? "=?base64?" . MIME::Base64::encode_base64 (AnyEvent::MCP::utf8enc ($name), "") . "?="
: $name;
}
}
my ($buffer, $sse, $received, $failure) = ("", 0, 0);
my $limit = $self->{max_size} || 8 * 1024 * 1024;
weaken $self;
my $deliver = sub {
my ($response) = @_;
if (ref $response eq "HASH" && !exists $response->{method}) {
die "HTTP response id mismatch\n"
unless exists $message->{id} && defined $response->{id}
&& "$response->{id}" eq "$message->{id}";
$received = 1;
}
$self->_receive ($response);
};
my $guard;
my $ok = eval {
$guard = AnyEvent::HTTP::http_request POST => $self->{url},
(map { exists $self->{$_} ? ($_ => $self->{$_}) : () }
qw(timeout proxy tls_ctx handle_params sessionid on_prepare on_connect tcp_connect)),
headers => \%headers,
body => JSON::XS::encode_json ($message),
recurse => 0,
persistent => 0,
on_header => sub {
my ($hdr) = @_;
return 0 unless $self && $self->{generation} == $generation;
$sse = $hdr->{"content-type"} =~ m{\Atext/event-stream(?:\s*;|\z)}i;
if ($message->{method} eq "initialize" && $hdr->{Status} >= 200 && $hdr->{Status} < 300
&& defined $hdr->{"mcp-session-id"}) {
$self->{session} = $hdr->{"mcp-session-id"};
}
1
},
on_body => sub {
my ($chunk, $hdr) = @_;
return 0 unless $self && $self->{generation} == $generation;
$buffer .= $chunk;
my $ok = eval {
if ($sse) {
while ($buffer =~ s/\A(.*?)(?:\r\n\r\n|\n\n|\r\r)//s) {
my $event = $1;
die "SSE event exceeds size limit\n" if length $event > $limit;
my @data = $event =~ /^data:[ \t]?(.*?)(?:\r?$)/mg;
$deliver->(JSON::XS::decode_json join "\n", @data) if @data;
}
}
die "HTTP response exceeds size limit\n" if length $buffer > $limit;
1
};
$failure = $@ unless $ok;
$ok
( run in 1.883 second using v1.01-cache-2.11-cpan-234fa220139 )