Amazon-API-Help

 view release on metacpan or  search on metacpan

lib/Amazon/API/Help.pm  view on Meta::CPAN

      documentation    => $service_meta->{metadata}{documentation} // $EMPTY,
      operations       => [ sort keys %{ $service_meta->{metadata}{operations} } ],
      botocore_version => $self->get_provenance->{version},
    },
  );

  return $SUCCESS;
}

########################################################################
sub snake_case {
########################################################################
  my ($name) = @_;

  while ( $name =~ s/([[:upper:]])([[:lower:]])/lc("_$1").$2/xsme ) { }

  $name =~ s/^_//xsm;
  $name =~ s/([[:lower:]])([[:upper:]])/$1_$2/gxsm;

  return $name;
}

########################################################################
sub _html2pod {
########################################################################
  my ($html) = @_;

  my $pod = Pod::HTML2Pod::convert(
    a_href  => $TRUE,
    a_name  => $TRUE,
    content => $html // $EMPTY,
  );

  $pod =~ s/^=pod//xsm;
  $pod =~ s/^=cut//xsm;
  $pod =~ s/^[#].*$//gxsm;

  $pod =~ s/\A\s+//xsm;  # template owns leading/trailing blank lines
  $pod =~ s/\s+\z//xsm;

  return $pod;
}

########################################################################
sub _show_pod {
########################################################################
  my ( $self, %args ) = @_;

  my $tt = $self->_template_engine;

  my $pod = $EMPTY;

  $tt->process( $args{template}, $args{stash}, \$pod )
    or die sprintf "ERROR: rendering %s: %s\n", $args{template}, $tt->error;

  my $paged;

  if ( $self->get_cli_pager ) {
    $paged = eval {
      require IO::Pager;
      IO::Pager::open( *STDOUT, '|-:utf8', 'Unbuffered' );
      return $TRUE;
    };
  }

  binmode STDOUT, ':encoding(UTF-8)'
    if !$paged;

  Pod::Text->new->parse_string_document($pod);

  return;
}

########################################################################
sub _template_engine {
########################################################################
  my ($self) = @_;

  my $tt = $self->get_tt;

  return $tt
    if $tt;

  $tt = Template->new(
    { INCLUDE_PATH => [ dist_dir('Amazon-API-Help') ],
      STRICT       => $TRUE,
      ENCODING     => 'utf8',
      FILTERS      => { html2pod => \&_html2pod },
    }
  ) or die sprintf "ERROR: could not create template engine: %s\n", Template->error;

  $self->set_tt($tt);

  return $tt;
}

########################################################################
sub cmd_dump_service {
########################################################################
  my ($self) = @_;

  my ($service) = $self->get_args;

  die "ERROR: usage dump-service service-name\n"
    if !$service;

  my $service_meta = $self->get_services->{$service};

  die "ERROR: no such service '$service'\n"
    if !$service_meta;

  print {*STDOUT} JSON->new->pretty->encode($service_meta);

  return $SUCCESS;
}

########################################################################
sub cmd_version {
########################################################################
  my ($self) = @_;

  my $version = Amazon::API::BuildInfo->version();

  require Text::ASCIITable;

  my $t = Text::ASCIITable->new( { headingText => 'Amazon::API Version Info' } );

  $t->setCols( q{}, qw(Version Commit) );
  $t->addRow( 'Amazon::API', $version->{version},                     $version->{commit} );
  $t->addRow( 'Botocore',    $version->{botocore_version}->{version}, $version->{botocore_version}->{commit} );

  print {*STDOUT} $t;

  return $SUCCESS;
}

########################################################################
sub main {
########################################################################
  my %commands = (
    'dump-service' => \&cmd_dump_service,
    'help'         => \&cmd_help,
    'version'      => \&cmd_version,
    'default'      => 'help',
  );

  my @option_specs = qw(



( run in 3.533 seconds using v1.01-cache-2.11-cpan-1bcd28dbaf1 )