view release on metacpan or  search on metacpan

lib/Acme/MomoiroClover/Members/Base.pm  view on Meta::CPAN

package Acme::MomoiroClover::Members::Base;

use strict;
use warnings;
use Date::Simple ();
use base qw(Class::Accessor);

our $ansi_colors = {
  red    => "\x1b[38;5;1m",
  green  => "\x1b[38;5;2m",
  blue   => "\x1b[38;5;4m",
  purple => "\x1b[38;5;5m",
  pink   => "\x1b[38;5;13m",
  yellow => "\x1b[38;5;3m",
};


__PACKAGE__->mk_accessors(qw(
    name_ja
    first_name_ja
    family_name_ja
    name_en
    first_name_en
    family_name_en
    nick
    birthday
    age
    blood_type
    hometown
    emoticon
    graduate_date
    join_date
    color
));

sub new {
    my $class = shift;
    my $self  = bless {}, $class;

    $self->_initialize;

    return $self;
}

sub say {
    my ($self, $comment) = @_;
    print $ansi_colors->{$self->color} if ($self->color);
    print $self->nick->[0] || $self->name_ja;
    print  ': ';
    print $comment, "\x1b[0m\n";
}

sub _initialize {
    my $self = shift;
    my %info = $self->info;

    $self->{$_}      = $info{$_} for keys %info;
    $self->{name_ja} = $self->family_name_ja.$self->first_name_ja;
    $self->{name_en} = $self->first_name_en.' '.$self->family_name_en;
    $self->{age}     = $self->_calculate_age;

    return 1;
}

sub _calculate_age {
    my $self  = shift;
    my $today = Date::Simple::today;

    if (($today->month - $self->birthday->month) == 0) {
        if (($today->day - $self->birthday->day) >= 0) {
            return $today->year - $self->birthday->year;
        } else {
            return ($today->year - $self->birthday->year) - 1;
        }
    } elsif (($today->month - $self->birthday->month) > 0) {
        return $today->year - $self->birthday->year;
    } else {
        return ($today->year - $self->birthday->year) - 1;
    }
}

1;

__END__

=head1 NAME

Acme::MomoiroClover::Members::Base - A baseclass of the class represents each
member of Momoiro Clover

=head1 SYNOPSIS

  use Acme::MomoiroClover::Z;

  my $momoclo_chan = Acme::MomoiroClover::Z->new;

  # retrieve the members as a list of
  # Acme::MomoiroClover::Base based objects