view release on metacpan or  search on metacpan

lib/Acme/AwesomeQuotes.pm  view on Meta::CPAN

use strict;
use warnings;
use utf8;
use 5.008_003;

package Acme::AwesomeQuotes;
BEGIN {
  $Acme::AwesomeQuotes::VERSION = '0.02';
}

binmode STDIN,  ':utf8';
binmode STDOUT, ':utf8';
binmode STDERR, ':utf8';

use Exporter;
our @ISA = qw(Exporter);
our @EXPORT_OK = qw(GetAwesome);
our @EXPORT    = qw(GetAwesome);

use Carp qw(croak);
use Unicode::Normalize qw(NFC NFD);

# ABSTRACT: Make your text awesome!


my %chartypes = (
                 'all'      => qr/[\x{030C}\x{0300}\x{0301}]/,
                 'notgrave' => qr/[^\P{NonspacingMark}\x{0300}]/,
                 'notacute' => qr/[^\P{NonspacingMark}\x{0301}]/,
                 'notcaron' => qr/[^\P{NonspacingMark}\x{030C}]/,
                 'puncsep'  => qr/[\p{Separator}\p{Punctuation}]/,
                );


sub GetAwesome {
	(my $string = NFD($_[0])) =~ s/(?:^${chartypes{puncsep}}+|${chartypes{puncsep}}+$)//g;

	eval {checkstring($string)} or croak $@;

	# For individual characters, use a caron instead of terminal acute/grave accents:
	if ($string =~ /^\p{Letter}\p{NonspacingMark}*$/) {
		# Prep string – remove extant carons/accents:
		$string =~ s/^(\p{Letter}${chartypes{notcaron}}*)${chartypes{all}}+(${chartypes{notcaron}}*)$/$1$2/;

		# Make string awesome!
		$string = NFC($string);
		$string =~ s/^(.*)$/`$1\x{030C}´/;
	}
	else {
		# If there are initial acute/terminal grave accents, use a caron instead:
		my $initialaccent = ($string =~ s/^(\p{Letter}\p{NonspacingMark}*)[\x{0301}\x{030C}]+/${1}/g)
		  ? "\x{030C}" : "\x{0300}";
		my $finalaccent   = ($string =~ s/(\p{Letter}\p{NonspacingMark}*)[\x{0300}\x{030C}]+(\p{NonspacingMark}*)$/${1}${2}/g)
		  ? "\x{030C}" : "\x{0301}";

		# Prep string – remove extant terminal acute/grave accents:
		$string =~ s/^(\p{Letter}${chartypes{notgrave}}*)\x{0300}/$1/;
		$string =~ s/(\p{Letter}${chartypes{notacute}}*)\x{0301}(${chartypes{notacute}}*)$/$1$2/;

		# Make string awesome!
		$string = NFC($string);
		$string =~ s/^(\p{Letter}\p{ModifierLetter}*)/`${1}${initialaccent}/;
		$string =~ s/(\p{Letter}\p{ModifierLetter}*)$/${1}${finalaccent}´/;
	}

	return(NFC($string));
}


sub checkstring {
	my $string = $_[0];
	if ($string eq '') {
		die "String is empty!\n";
	}
	elsif ((($string =~ /^`\p{Letter}${chartypes{notgrave}}*\x{0300}/) &&
	        ($string =~ /\p{Letter}${chartypes{notacute}}*\x{0301}${chartypes{notacute}}*´$/)) ||
	       ($string =~ /^`\p{Letter}${chartypes{notcaron}}*\x{030C}${chartypes{notcaron}}*´$/)) {
		die "String '$string' is *already* awesome!\n";
	}
	elsif ($string !~ /^\p{Letter}/) {
		die "String '$string' begins with a non-letter character.\n";
	}
	elsif ($string !~ /\p{Letter}\p{NonspacingMark}*$/) {
		die "String '$string' terminates with a non-letter character.\n";
	}
	else {
		1;
	}
}


1; # This is a module, so it must return true.

__END__
=pod

=encoding utf-8

=head1 NAME

Acme::AwesomeQuotes - Make your text awesome!

=head1 VERSION

version 0.02

=head1 SYNOPSIS

  use Acme::AwesomeQuotes;
  my $awesome_text = GetAwesome('Wyld Stallyns');
  say q(I'm Bill S. Preston, Esquire!);
  say q(And I'm Ted "Theodore" Logan!);
  say ('And we are ', $awesome_text, '!');

=head1 DESCRIPTION

Tired of ordinary quotation marks that lack punch?

Looking for something that can better convey just how I<awesome> your words are?

You need `àwesome quoteś´!

=head1 FUNCTIONS

=head2 GetAwesome

C<GetAwesome()> is the module’s only function, and is exported by default. It takes a single scalar string argument, and returns that string with the following changes applied:

=over 4

=item *

a grave accent (or backtick, U+0060) is prepended;

=item *

a combining grave accent is added to the first letter;