view release on metacpan or  search on metacpan

examples/v201309/basic_operations/delete_ad_group.pl  view on Meta::CPAN

use strict;
use lib "../../../lib";

use Google::Ads::AdWords::Client;
use Google::Ads::AdWords::Logging;
use Google::Ads::AdWords::v201309::AdGroup;
use Google::Ads::AdWords::v201309::AdGroupOperation;

use Cwd qw(abs_path);
use Data::Uniqid qw(uniqid);

# Replace with valid values of your account.
my $ad_group_id = "INSERT_AD_GROUP_ID_HERE";

# Example main subroutine.
sub delete_ad_group {
  my $client = shift;
  my $ad_group_id = shift;

  # Create ad group with DELETED status.
  my $ad_group = Google::Ads::AdWords::v201309::AdGroup->new({
    id => $ad_group_id,
    # When deleting an ad group, it is a good practice to also rename it to
    # avoid name collisions when creating new ad groups.
    name => "Deleted Ad Group - " . uniqid(),
    status => "DELETED"
  });

  # Create operation.
  my $operation = Google::Ads::AdWords::v201309::AdGroupOperation->new({
    operand => $ad_group,
    operator => "SET"
  });

  # Delete ad group.
  my $result = $client->AdGroupService()->mutate({
    operations => [$operation]
  });

  # Display ad groups.
  if ($result->get_value()) {
    my $ad_group = $result->get_value()->[0];
    printf "The ad group with id \"%d\" was renamed to \"%s\" and deleted.\n",
           $ad_group->get_id(), $ad_group->get_name();
  } else {
    print "No ad group was deleted.\n";
  }

  return 1;
}

# Don't run the example if the file is being included.
if (abs_path($0) ne abs_path(__FILE__)) {
  return 1;
}

# Log SOAP XML request, response and API errors.
Google::Ads::AdWords::Logging::enable_all_logging();

# Get AdWords Client, credentials will be read from ~/adwords.properties.
my $client = Google::Ads::AdWords::Client->new({version => "v201309"});

# By default examples are set to die on any server returned fault.
$client->set_die_on_faults(1);

# Call the example
delete_ad_group($client, $ad_group_id);