view release on metacpan or  search on metacpan

configure.ac  view on Meta::CPAN

dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.5)

dnl Some handy macros
define([THE_PACKAGE_NAME],    [dta-tokwrap])
define([THE_PACKAGE_VERSION], [0.98])
define([THE_PACKAGE_MAINTAINER],  [moocow@cpan.org])

AC_INIT(THE_PACKAGE_NAME, THE_PACKAGE_VERSION, THE_PACKAGE_MAINTAINER)

dnl source && aux dir
AC_CONFIG_AUX_DIR(.)

dnl canonical target (sets $target, $target_(cpu|vendor|os) : used for bindist)
AC_CANONICAL_TARGET

dnl use automake
AM_INIT_AUTOMAKE()

dnl use autoheader
AM_CONFIG_HEADER([src/dtatwConfigAuto.h])

dnl default prefix
AC_PREFIX_DEFAULT(/usr/local)

##-- save user flags
AX_SAVE_USERFLAGS()

##-- check for compilers (may alter CFLAGS, CXXFLAGS)
AC_PROG_CC
dnl AC_PROG_CXX
dnl AC_LANG(C++)

##-- DISTCHECK: simulate missing development-only packages
AX_ARG_DISTCHECK()

##-- flex, bison (also automake LEX, YACC)
AX_HAVE_GNU_MAKE()
AX_CHECK_FLEX()
AX_CHECK_BISON()
AX_GNU_LEXYACC()


dnl v--- needed if Makefile.am uses _LTLIBRARIES targets
dnl AC_PROG_LIBTOOL

dnl v--- for static-only libraries (non-libtool)
dnl AC_PROG_RANLIB

##---------------------------------------------------------------
## svn info
##  + keyword substitution requires property svn:keywords set on
##    this file:
##    $ svn propset svn:keywords "HeadURL Id" configure.ac
##  + or even:
##    $ svn propset svn:keywords "HeadURL Id Date Rev Author" configure.ac
AC_PATH_PROG([SVNVERSION],[svnversion],[no])

AC_MSG_CHECKING([for SVN HeadURL])
SVNURL=`echo '$HeadURL: svn+ssh://svn.dwds.de/home/svn/dev/dta-tokwrap/trunk/configure.ac $' \
  | sed -e's/^\$HeadURL:[ ]*//1' -e's/\/configure.ac[ ]*\$$//1'`
AC_MSG_RESULT([$SVNURL])

AC_MSG_CHECKING([for SVN revision of working copy])
if test -n "$SVNVERSION" -a "$SVNVERSION" != "no"; then
  SVNREV=`$SVNVERSION -n`
else
  SVNREV='exported'
fi
AC_MSG_RESULT([$SVNREV])

SVNID="${SVNURL} @ ${SVNREV}"
AC_SUBST(SVNURL)
AC_SUBST(SVNREV)
AC_SUBST(SVNID)
AC_DEFINE_UNQUOTED(PACKAGE_SVNURL, "$SVNURL", [Subversion HeadURL of package sources])
AC_DEFINE_UNQUOTED(PACKAGE_SVNREV, "$SVNREV", [Current SVN revision of package sources])
AC_DEFINE_UNQUOTED(PACKAGE_SVNID,  "$SVNID",  [Subversion identifier for package sources])
##
## svn info
##---------------------------------------------------------------

#---------------------------------------------------------------
# short package include-dir
spkgincludedir="\${includedir}/AC_PACKAGE_NAME"
AC_SUBST(spkgincludedir)
# short package include-dir
#---------------------------------------------------------------

#---------------------------------------------------------------
# share/package dir
sharepkgdir="\${prefix}/share/AC_PACKAGE_NAME"
pkgxsldir="\${sharepkgdir}/stylesheets"
pkgmakdir="\${sharepkgdir}/make"
pkgdocdir="\${sharepkgdir}/doc"
AC_SUBST(sharepkgdir)
AC_SUBST(pkgxsldir)
AC_SUBST(pkgmakdir)
AC_SUBST(pkgdocdir)
# share/package dir
#---------------------------------------------------------------

#---------------------------------------------------------------
# resource dir (for e.g. dta_abbrevs.lex, dta_mwe.lex)
AC_ARG_WITH([rcdir],
	AC_HELP_STRING([--with-rcdir=DIR],
		[default directory in which to look for shared resources (default=DATADIR/dta-resources]),
	[rcdir="$withval"],
	[rcdir="\${datadir}/dta-resources"])
AC_SUBST(prefix)
AC_SUBST(datadir)
AC_SUBST(rcdir)
# /resource dir
#---------------------------------------------------------------